はじめに
uGUIにもマスクの機能がありますが、曲線を含むマスクを掛けようと思うとジャグジャギして使えません。マスク用画像でマスクするシェーダーを自作することが多いと思いますが、今回はパラメータで角丸の比率を変えられるシェーダーを作ってみようと思います。
memo!
uGUIのマスクがジャギるのは、たぶんアルファクリップなのでアンチエイリアスが効かないからだと思います。
雛形のシェーダーを入手
unityのダウンロードサイトからビルトインシェーダーのセットをダウンロードします。UI-Default.shaderを探してプロジェクトにコピーします。
実装方法を考える
rounded corner shaderというキーワードで検索してみると以下のサイトが見つかりました。
以下の部分が肝みたいですが、パッと見でなにをしているかさっぱりわかりません。
return length(max(abs(CenterPosition)-Size+Radius,0.0))-Radius;
考察する
自分ならどう実装するかを考えながらソースを眺めていたらわかりました。かんたんに解説します。
- 例えば150pxの画像を20pxの半径で角丸にしたい時
- 四隅から20px小さくした角からの距離を見て
- xy共にプラス方向で20pxより離れてれば抜く
という計算になります。
シェーダを改造
上記のような計算をシェーダーで処理を書くときは、極力シンプルかつ制御構文を使わず計算だけで実現する方法を考えます。頂点シェーダー内なら多少if分があってもいいと思いますが、ピクセルシェーダー内で行う計算なので最適化を考えていきます。
Shader "UI/Rounded"
{
Properties
{
[PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
_Color ("Tint", Color) = (1,1,1,1)
_StencilComp ("Stencil Comparison", Float) = 8
_Stencil ("Stencil ID", Float) = 0
_StencilOp ("Stencil Operation", Float) = 0
_StencilWriteMask ("Stencil Write Mask", Float) = 255
_StencilReadMask ("Stencil Read Mask", Float) = 255
_ColorMask ("Color Mask", Float) = 15
[Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
_Round ("角丸", Range(0,1)) = 0
}
SubShader
{
Tags
{
"Queue"="Transparent"
"IgnoreProjector"="True"
"RenderType"="Transparent"
"PreviewType"="Plane"
"CanUseSpriteAtlas"="True"
}
Stencil
{
Ref [_Stencil]
Comp [_StencilComp]
Pass [_StencilOp]
ReadMask [_StencilReadMask]
WriteMask [_StencilWriteMask]
}
Cull Off
Lighting Off
ZWrite Off
ZTest [unity_GUIZTestMode]
Blend One OneMinusSrcAlpha
ColorMask [_ColorMask]
Pass
{
Name "Default"
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma target 2.0
#include "UnityCG.cginc"
#include "UnityUI.cginc"
#pragma multi_compile_local _ UNITY_UI_CLIP_RECT
#pragma multi_compile_local _ UNITY_UI_ALPHACLIP
struct appdata_t
{
float4 vertex : POSITION;
float4 color : COLOR;
float2 texcoord : TEXCOORD0;
UNITY_VERTEX_INPUT_INSTANCE_ID
};
struct v2f
{
float4 vertex : SV_POSITION;
fixed4 color : COLOR;
float2 texcoord : TEXCOORD0;
float4 worldPosition : TEXCOORD1;
float4 mask : TEXCOORD2;
UNITY_VERTEX_OUTPUT_STEREO
};
sampler2D _MainTex;
fixed4 _Color;
fixed4 _TextureSampleAdd;
float4 _ClipRect;
float4 _MainTex_ST;
float _UIMaskSoftnessX;
float _UIMaskSoftnessY;
float _Round;
v2f vert(appdata_t v)
{
v2f OUT;
UNITY_SETUP_INSTANCE_ID(v);
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
float4 vPosition = UnityObjectToClipPos(v.vertex);
OUT.worldPosition = v.vertex;
OUT.vertex = vPosition;
float2 pixelSize = vPosition.w;
pixelSize /= float2(1, 1) * abs(mul((float2x2)UNITY_MATRIX_P, _ScreenParams.xy));
float4 clampedRect = clamp(_ClipRect, -2e10, 2e10);
float2 maskUV = (v.vertex.xy - clampedRect.xy) / (clampedRect.zw - clampedRect.xy);
OUT.texcoord = TRANSFORM_TEX(v.texcoord.xy, _MainTex);
OUT.mask = float4(v.vertex.xy * 2 - clampedRect.xy - clampedRect.zw, 0.25 / (0.25 * half2(_UIMaskSoftnessX, _UIMaskSoftnessY) + abs(pixelSize.xy)));
OUT.color = v.color * _Color;
return OUT;
}
fixed4 frag(v2f IN) : SV_Target
{
half4 color = IN.color * (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd);
#ifdef UNITY_UI_CLIP_RECT
half2 m = saturate((_ClipRect.zw - _ClipRect.xy - abs(IN.mask.xy)) * IN.mask.zw);
color.a *= m.x * m.y;
#endif
// uv座標(0~1)から(-1,1)の座標に変換
float2 pos = IN.texcoord * 2 - 1;
// 4角を意識しなくていいように全て右上の座標(0~1)にする
float2 fixedPos = abs(pos);
// 半径分小さくした角の座標（半径は割合）
float2 corner = 1 - _Round;
// 小さくした角からの位置
float2 localPos = fixedPos - corner;
// マイナスになる座標は0にして距離を計算（角から見て右上方向以外は半径の長さを超えなくなる）
float distance = length(max(localPos, 0));
// 半径より離れているか
float fixedDistance = distance - _Round;
// これだとややジャギル
//color.a = 1 - step(0, fixedDistance);
// これがアンチエイリアスっぽくなる
color.a = 1 - smoothstep(0, .01, fixedDistance);
#ifdef UNITY_UI_ALPHACLIP
clip (color.a - 0.001);
#endif
color.rgb *= color.a;
return color;
}
ENDCG
}
}
}
note!
// uv座標(0~1)から(-1,1)の座標に変換 float2 pos = IN.texcoord * 2 - 1; // 4角を意識しなくていいように全て右上の座標(0~1)にする float2 fixedPos = abs(pos); // 半径分小さくした角の座標（半径は割合） float2 corner = 1 - _Round; // 小さくした角からの位置 float2 localPos = fixedPos - corner; // マイナスになる座標は0にして距離を計算（角から見て右上方向以外は半径の長さを超えなくなる） float distance = length(max(localPos, 0)); // 半径より離れているか float fixedDistance = distance - _Round; // これだとややジャギル //color.a = 1 - step(0, fixedDistance); // これがアンチエイリアスっぽくなる color.a = 1 - smoothstep(0, .01, fixedDistance);
今回追記した部分です。先ほどの考察結果を式にしました。smoothstepをつかってアンチエイリアス感を出しているのがポイントです。
おわりに
サンプル画像にLennaを使いたかったのですが、本人が使わないで欲しいと言っているようなのでマンドリルを使いました。
memo!
ja.wikipedia.org 画像圧縮とLennaについて知っていると面白いです。
www.ess.ic.kanagawa-it.ac.jp マンドリルは↑から頂きました。
